The music was created from the Zel code below. The piece comprises 18 MIDI tracks using 12 MIDI channels and it has 3670 MIDI events. The MP3 was recorded on a Roland SC-55 (in 5 takes because the polyphony was too much for this older synth). If you try to play the MIDI file, and you notice instruments cutting out, thats probably because there are too many voices for your MIDI device.
'Excerpt from Rachmaninov`s Piano Concerto No. 2
list
'include tg33.zel generalMIDI
include gm.zel
set [ lowTimpani {g} highTimpani {C} ]
tempo=132 meter 4/4 key a
'SET UP THE TRACKS
track [ P_no Fl FlH Ob ObL Cl Fag Cor Tr_be Tr_ni
Tuba Perc Violin1 Violin2 Violin2L Viola Cello Bass ]
'NOTICE WE SET THE OCTAVE BEFORE ISSUING THE PATCH. THIS ALLOWS US TO
'ADJUST THE OCTAVE IN THE SYNTH FILE IF NEC. e.g. @@+1
P_no $$1 @@6 acousticGrandPiano !!+40
Fl $$3 @@5 flute
FlH $$3 @@6 flute 'MUST RE-ISSUE TO SET OCTAVE
Ob $$4 @@5 oboe
ObL $$4 @@4 oboe
Cl $$5 @@5 clarinet
Fag $$6 @@4 bassoon
Cor $$7 @@6 frenchHorn
Tr_be $$8 @@6 trumpet !!+40 ##=-2
Tr_ni $$9 @@5 trombone
Tuba $$11 @@4 tuba
Perc $$14 @@3 timpani !!+32
Violin1 $$12 @@6 stringEnsemble1 !!+40
Violin2 $$13 @@6 stringEnsemble2 !!+40
Violin2L $$12 @@5 stringEnsemble1 !!+40
Viola $$13 @@5 stringEnsemble2 !!+40
Cello $$12 @@4 stringEnsemble1 !!+64
Bass $$12 @@4 stringEnsemble1 !!+40
'TRACK GROUPS:
track [
FlutesH_L [Fl FlH]
OboesH_L [Ob ObL]
Violins [Violin1 Violin2]
ViolinEns [Violins]
Strings [Violins Violin2L Viola Cello]
Ob_Cl [Ob Cl]
Ob_ClEns [Ob_Cl]
Ob_Cl_Fag [Ob Cl Fag]
Ob_Cl_FagEns [Ob_Cl_Fag]
Fag_Cor [Fag Cor]
Fag_CorEns [Fag_Cor]
Fl_Strings [FlutesH_L Strings]
Fl_StringsEns [Fl_Strings]
Fl_Ob_Strings [Fl_Strings OboesH_L]
Fl_Ob_StringsEns [Fl_Ob_Strings]
Orchestra [Fl_Strings Ob_Cl_Fag Cor Tr_be Tr_ni Tuba Bass]
]
set q2 {aA DF AA@ D@F@ AA@ gG DF GG@ @+1DF GG@}
'The timpanyRoll macro takes a single argument specifying
'how long the roll should be:
set timpaniRoll { (({lowTimpani}/4 {lowTimpani}/4 )2~)?1 }
P_no @@6 duration /4
'Done with this duration because some sequencers
'cannot handle the correct tempo of 264
| 2 (q2 )2~ @@-1 (q2 )2~ @@+1 (q2 )3~ tempo 9-60 +48
GG@ B G@ G@ B@ G4@G@+2
| time T1 duration 1
set theme { G C3@ B& G F G5 E F E A& G F E G F E D G5 };
Fl_Ob_StringsEns T1 1
theme time T2
Cl T1
##-2 (key D D4F | E&4G | D8A5 F G F | C^4D | b&4C a8D)~
Fag T1
C4E D&4F C8G5 E F E b&4C a&4b^ g8C
Cor T1
##-7 d4gb d4fa&C | d8gD | f4gF e&4f#E& | d8GD time T3;
Tr_be T1
D4f#
Tr_ni T1
C4e 8 g8c 16 g8c
Tuba T1
c4g 8 c8g 16 c8g
Perc T1
{lowTimpani} 8 {timpaniRoll,8} 16 {timpaniRoll,8}
P_no T1 @@6
1 g2CEG gCEG | 1 g2b&D&FG gb&D&FG | /2 f/gCF e/gCF f/gCF
e/gCE E/GC@E@ E/GC@E@ E&/GC@E@ |E/GC@E@ C/EGC@ G/C@ C/G C/G
g/C g/C c/g | 1 e2b&C ebc | 1 d2fB^ dfb | /2 f/gCF e/gCE f/gCF
e/gCE F/GC@F@ E/GC@E@ F/GC@F@ E/GC@E@ C/EGC@
P_no T1 @@4
cc@ E2GC@E@ EGC@E@ | cc@ F2B&D&@F@ FBD@F@ | /2 g/CF g/CE
g/CF g/CE E/GC@E@ E/GC@E@ E&/GC@E@ | E/GC@E@ E/GC@ G/C@ c/G c/G
g/C g/C | cc@ C2B&C@ CBC@ | cc@ C2A&B CA&B | /2 g/CF g/CE g/CF
g/CE F/GC@F@ E/GC@E@ F/GC@F@ E/GC@E@ E/GC@
Bass T1
c4 c4 c8 c4 c4 c8
set [ theme1 {C D D# | E5 C E F G F E3 }
theme2 {@@+1 g C D E F2 E E3 D C b a C } ]
Fl_Ob_StringsEns T2
theme1 'bar 13.5 or so
Cl T2
| (key D C4E | b4D | E2G D4F ) ##+2
Fag T2
| b4D a4C D2F C4G
Cor T3
b7@f#4a4b7 e4g 3 Cc | d8a2C2D8 b6g
P_no T2 duration /2 @@6
GC@ CG CG gC GC CG | 2 e6bde | 2 a4@ce c2ac |
2 g2@dfg 4 g4CEG 'g4CEG g2@cg
P_no T2 @@4 GC@ CG CG gC gC cg | g#2g@ E6BD@ | a2a@ a4E e2A |
b2b@ g2df c2c@ E4GC@E@
time T1 duration 1
Bass
@@-1 g#4 a4 b2 C6
'----------------------------------------------------------------------
Fl_StringsEns T1
theme2
Ob_Cl_FagEns T1
1 E2G D4G# | C4A C4D
Cor T1
| a4D# | g4E g4a ##+7
Tr_ni T1
| g#4D | a4C | a4C
Tuba T1
| e4D | f4C | f#4D
P_no T1 @@6 duration
/2 g2@cg | 1 DG#D@ CGC@ DGD@ CGC@ CGC@ bGB CGC@ |
1 CFC@ bFB CFC bFB aFA aFA fC | 1 aDA aDA aD 2 daD daD da |
P_no T1 @@4
gC | 1 ( DG# )7(D@ C@ D@ C@ B C@) | 1 ( CF )7( C@ B C@ B A A A) |
1 AD@ aD@ DA 2 DA DA f#D
duration 1 time T1;
Bass E4 F4 F4#
'----------------------------------------------------------------------
Fl_StringsEns T1 'bar22 or so
g C E G |A& A^2 A& | A& D E F | G A^2 G | G C# D E | E F F E
E D D E |E2 D C | C e e d |
Ob_ClEns T1
C2E EG GC@ | G&4C@ | F4C@ | F4B3 B& | G4A | D4A | D4G# | F4A | C4D
Fag_CorEns T1
C2E E2G | g&4A&1 A^2 A& | F4A& | F4G1 A2^ G | E4G | a4D | g#4D | a8C
Tr_be T1
20 | b4 a#4 g4b e4
Tr_ni T1
g4C g&4C f4C f4b3 b& | g4a a4D b4D a8C
Tuba T1
g4E a&4@a d4D g4@g | a4@a d4D | e4E f4F f#4F
Perc T1
28 {timpaniRoll,8}
P_no @@6 duration /2
| 1 CEGC@ CEGC@ gCEG 2 gCEG gCEG egCE
| 1 @@+1 a&CG&A a^CGA aCGA aCGA a&CGA aCGA gG
| 2 a&4@cea a2CFA
| 1 gbFG a^bFA abFA abFA gbFG gb&FG fF
| 2 g4@c#eg g2C#EG
| 1 aDA aDA daD daD da a@da a@da
| 1 g#DG gDG dgD dgD dg g@dg g@d
| 2 a2@@c@f@a@ a2@cfa a2CFA
| 2 d4@a@c d2aCD
P_no T1 @@4
| 1 EGC@E EGC@E cEGC 2 cEGC cEGC gCEG @@+1
| a&@a@@ aCG&A a^CGA aCGA aCGA a&CGA aCGA gG
| d2@d@@ f4a&CF F2AC@F@
| g@g@@ gbFG a^bFA abFA abFA gbFG gb&FG fF
| a2@a@@ e4GC#E E2GC#@E@
| d@d@@ aDA aDA fCF fCF fC cFC cF
| e@e@@ g#DG gDG dgD dgD dg g@DG gD
| f2@f@@ f2@a@cf f2aCF F2AC@F@
| f2#@f@@ d4aC a2CDA
Bass duration 1
| G4 A4& D4 G4 a4 D4 E4 F4 F#4
time T1
'-----------------------------------------------------------------------
restart
set [
stac {**/3}
leg {**1}
]
+ tempo=160
Orchestra stac !!+20 'PUT WHOLE ORCHESTRA INTO LOUD STACCATO MODE
Fl
CG | 3 f#C |gD aE& b&E^ b^F^ |CG GA F#A F^B | EC@
3fg | eC 3 a&C | g#E a^C# aD D@A | leg C2G4 b2 | stac C
3a&C | gE 3 aD# | EG C#A DA AD | leg !+20 C^2G4 b2
Ob
EG | 3 f#C |gD aE& b&E^ b^F^ |CG GA F#A F^B | EC@
3fg | eC 3 a&C | g#E a^C# aD D@D | leg C2G4 b2 | stac C
3a&C | gE 3 aD# | EG C#A DA AD | leg !+20 C^2G4 b2
Cl (key D ##-2
FA | 3 eg# |eg ab aC^ aC# |aD DA DG# CG^ | DF
3cg| df 3 d | e fb eb eD | leg g4G stac | fD 3
de | df 3 bC | aC bD# bE bE | leg g4G stac)
Fag
EG | 3 aD |bD CG C#G DG |EG E&C@ DC@ GD@ debug_off
| cC@ leg a2 stac gG@ | CG leg E2 stac FA& |
| EB# aA^ fF bC | leg g4G | stac cC leg E2 stac
FA& | CG leg A2 stac BD#@ | EE@ aA fF f#F | leg
g4G |
Cor ##-7
dgbD | 3 c#agC# dCaD db&eD db^fD dCf#D | dDgD gDE gC#E f#C^D |
dgb leg c#2gb c^fC | 1 a2e&E& geE | 1 stac g#eE aeE eag |
leg d4g2C4D f#2 | stac dgb leg e&2Ea stac eEg | 1 leg b2C#G
stac a#F#E | 1 g#Ee aeE eEa | leg d4CDg2 f#2
Tr_be
aD | 1 | 1 | 1da dg# g^C# | f#D | 8 | leg a4 | d | 8 a4
Tr_ni
CE | 11 gb | gC | 8 | leg g4D2 C2 | eC | f4C2 b2 |
Tuba
gG | 10 dD gG | cC | 8 | leg g4g@ | cC | 8 g4g@ |
Perc
{lowTimpani} | 8 | 3 {lowTimpani} | {highTimpani} |
8 | {timpaniRoll,4} | {highTimpani}
Violin1
g@eCG | 3 dC | dD E& E^ F | G aA aA DB | EC@ leg e2 stac g
eC leg g#2 stac C | E C# D A | leg G4 | C g#2 C | stac
CE leg C2 stac D# | G aA aA aD@ | leg G4
Violin2
g@eC | 3 f# | f^g@ gg@ gg@ gg@ | gg@ ga f#a f^ |
G@Ec leg C2 stac G@F | G@E leg D2 stac a& | g# ea da dD |
leg d4C2 b2 | eC leg d2 stac a& | g@g leg f#2 stac a
| bE C# D aA | leg d4C2 b2
Viola
gEC@ | 3 f# | g a b& b^ | C cC cC gD | cgE
leg f#2 stac g | gE g#2D C | g#D E D DA | leg g4F stac
| ge leg g#2 stac C | gE leg E2 stac D#A | E C# D DA |
leg g4F |
Cello
g | 3 a | b C C# D | E E&A dA G | C leg a2 stac g |
C leg E2 stac F | E A F F# | leg G4 stac C leg E2 stac F
|C leg A2 stac B | E A GA G#A | leg G4 |
Bass
g | 3 a | b C C# D | E E&A dA G | C leg a2 stac g |
C leg E2 stac F | E A F F# | leg G4 stac | C leg E2 stac
F | C leg A2 stac B | E A F F# | leg G4
P_no duration /3 @@6 (tempo=160 48+40)
(| 1 CEG g 2CEA a 2EGB b 2EGC@ C |)
| ce g@ 2a@ce g@ 2be g@ 2ce g@ |
(| 1 GC@D@ D 2GC@E@ E 2 C@D@F#@ F |)
| cdg g@ 2ceg g@ 2 cf a@ 2cdf# a@ |
(| 1 D@F@G@ G 2 G@@ G@ 2 G@ G 2 G g|)
| df^g b 2 G g 2 g g@ 2g@ g@@ |
(| 24| )
| g@ | 3 @@5 e f#CF# g aCA g aCA b baDA b
| C3EC@ g# aDA b CC@ b CC@ D CA&C@ D
(| @@6 e3g#E 4 C#g^ c 2 aD d 2 C^DA a)
| 3 a@ e 2 f@a@ d 2 f#@c d
(|@@7 1 cdg g@ 2CDG g bDG g b@dg g@ )
|@@6 g@c d 2 gC D 2 gb D 2 b@g@ f
|@@6 C3ce g#@ a@da b@ cC b@ cC d ca&C d
|e3gE c df#D d# efE d efeE f# eaE f#
|g3bG a@e gC#GA a f@a@d fDA a f#@a@d f#AC^@D@
|b@cd f^CDG g gCD FC@D@G@ G gbD FBD@G@ G gdF GB@D@@G@@ G@
'-----------------------------------------------------------------------
restart duration 1
set rhythm { stac ?1 2 leg *2 ?2 | stac ?3 2 leg *2 ?4 |
stac ?5 2 leg *2 ?6 | stac ?7 ?8 ?9 ?a | ?b 4 | ?c 2 ?d 2 |
?e 2 ?f ?g | ?h 2 ?i | ?j 2 ?k */ ?k */ ?k ?k};
Fl
{rhythm,C,CE,C,DE,C,bE,C,CE,aC,bE,
C,GC@,GC@,GC@,GC@,GC@,GC@,DG,GC@, }
Ob
{rhythm,C,CE,C,DE,C,bE,C,CE,aC,bE,
C,GC@,GC@,GC@,GC@,GC@,GC@,DG,GC@, }
Cl (key D
{rhythm,dD,fg#,fa,fC,fa,fC,fa,fb,df,fC,
fa,FD@,FD@,FD@,FD@,FD@,FD@,CA,FD@,a@d} )
Fag
{rhythm,CC@,AC@,GC@,G#B,G^C@,GB,GC@,AC@,AC@,EC@,
CC@,C@E@,C@E@,C@E@,C@E@,C@E@,C@E@,D@G@,C@E@,CE}
Cor
{rhythm,g,bC#,bD,ab,bD,bD,bD,bE,gb,bD,
bD,gbDG,gbdG,gbDG,gbDG,gbDG,gbDG,f#DaF#,gDbG,g@db@g}
Tr_be
{rhythm,d,DF#,f#D,C#F#,f#D,C#F#,f#D,DF#,bD,C#F#,
f#D,f#D,f#D,f#D,f#D,f#D,f#D,ea,f#D,d}
Tr_ni
{rhythm,eC,f#C,gC,eb,gC,eb,gC,ac,ac,eb,
gC,gC,gC,gC,gC,gC,gC,gb,gC,fa}
Tuba
{rhythm,cC,g@g,cC,g#@g,cC,g^@g,cC,f#,a,g,
cC,cC,cC,cC,cC,cC,cC,gG,cC,cC}
Perc
highTimpani | 8 | 1 highTimpani highTimpani lowTimpani |
highTimpani | (highTimpani 2 )3~ (highTimpani )3~ 1
lowTimpani | highTimpani 2 highTimpani {highTimpani}/2
{highTimpani}/2 | highTimpani
ViolinEns
{rhythm,C,eCE,EC,eDE,EC,egE,eC,eCE,eC,ebE,
eC,cgEC@,cgEC@,cgEC@,EC@,EC@,EC@,g@dbG,geCC@,c,g@}
Viola
{rhythm,C,f#,eg,e,eg,eg,eg,a,a,eb,
cC,cgEC@,cgEC@,cgEC@,EC@,EC@,EC@,gDB,cgEC@,e}
Cello
{rhythm,C,a,C,g#,C,g^,C,f#,a,g,
cC,cgEC@,cgEC@,cgEC@,cC,cC,cC,gDB,cgEC@,cC}
Bass
{rhythm,C,a,C,g#,C,g^,C,F#,A,G,
C,C,C,C,C,C,C,G,C,C}
set [gen { ?1 ?2 ?1 ?2 }
gen2 { ?1 *2 ?1 }]
P_no @@6 duration /4
C4EC@ {gen,
CEGC@, @+1 E@GC@E@,aEF#A,@+1 CEAC,f#CE,@+1 aCEA,
gCE,@+1 gCEG,cegC,EGC@E@,b@deb,EBD@E@,g#@deg#,bDEB,
g^@ceg,CEGC@,g@CE,gCEG,g@bE,gbE,e@g@b@,egb,
e@g@c,egC,c@e@a@,cea} @@-1 {gen,a@ce,aCE,g@be,gbE}
duration /3 |
(1 gC e2 {gen2,CEA,CEG,EGD@,EGC@,C@E@A@,C@E@G@,E@G@D@@} @@6
{gen2,egC,CEA,CEG,EGD@,EGC@,C@E@A@,BD@G@,F@G@D@@} 1 E@G@C@@
@@5 (duration 1 2 cC c/C c/C cC))
c3egC a3@cea g3@ceg d3egD | c3egC a3CEA g3CEG D3EGD@ |
C3EGC@ A3C@E@A@ G3C@E@G@ D3@E@G@D@@ C3@E@G@C@@ A3@C@@E@@A@@ @@+1
G3D@F@G@ D3@F@G@D@@ C@E@G@C@@
@@4 (duration 1 2 cc@ c/c@ c/c@ cc@)
list
'include tg33.zel generalMIDI
include gm.zel
set [ lowTimpani {g} highTimpani {C} ]
tempo=132 meter 4/4 key a
'SET UP THE TRACKS
track [ P_no Fl FlH Ob ObL Cl Fag Cor Tr_be Tr_ni
Tuba Perc Violin1 Violin2 Violin2L Viola Cello Bass ]
'NOTICE WE SET THE OCTAVE BEFORE ISSUING THE PATCH. THIS ALLOWS US TO
'ADJUST THE OCTAVE IN THE SYNTH FILE IF NEC. e.g. @@+1
P_no $$1 @@6 acousticGrandPiano !!+40
Fl $$3 @@5 flute
FlH $$3 @@6 flute 'MUST RE-ISSUE TO SET OCTAVE
Ob $$4 @@5 oboe
ObL $$4 @@4 oboe
Cl $$5 @@5 clarinet
Fag $$6 @@4 bassoon
Cor $$7 @@6 frenchHorn
Tr_be $$8 @@6 trumpet !!+40 ##=-2
Tr_ni $$9 @@5 trombone
Tuba $$11 @@4 tuba
Perc $$14 @@3 timpani !!+32
Violin1 $$12 @@6 stringEnsemble1 !!+40
Violin2 $$13 @@6 stringEnsemble2 !!+40
Violin2L $$12 @@5 stringEnsemble1 !!+40
Viola $$13 @@5 stringEnsemble2 !!+40
Cello $$12 @@4 stringEnsemble1 !!+64
Bass $$12 @@4 stringEnsemble1 !!+40
'TRACK GROUPS:
track [
FlutesH_L [Fl FlH]
OboesH_L [Ob ObL]
Violins [Violin1 Violin2]
ViolinEns [Violins]
Strings [Violins Violin2L Viola Cello]
Ob_Cl [Ob Cl]
Ob_ClEns [Ob_Cl]
Ob_Cl_Fag [Ob Cl Fag]
Ob_Cl_FagEns [Ob_Cl_Fag]
Fag_Cor [Fag Cor]
Fag_CorEns [Fag_Cor]
Fl_Strings [FlutesH_L Strings]
Fl_StringsEns [Fl_Strings]
Fl_Ob_Strings [Fl_Strings OboesH_L]
Fl_Ob_StringsEns [Fl_Ob_Strings]
Orchestra [Fl_Strings Ob_Cl_Fag Cor Tr_be Tr_ni Tuba Bass]
]
set q2 {aA DF AA@ D@F@ AA@ gG DF GG@ @+1DF GG@}
'The timpanyRoll macro takes a single argument specifying
'how long the roll should be:
set timpaniRoll { (({lowTimpani}/4 {lowTimpani}/4 )2~)?1 }
P_no @@6 duration /4
'Done with this duration because some sequencers
'cannot handle the correct tempo of 264
| 2 (q2 )2~ @@-1 (q2 )2~ @@+1 (q2 )3~ tempo 9-60 +48
GG@ B G@ G@ B@ G4@G@+2
| time T1 duration 1
set theme { G C3@ B& G F G5 E F E A& G F E G F E D G5 };
Fl_Ob_StringsEns T1 1
theme time T2
Cl T1
##-2 (key D D4F | E&4G | D8A5 F G F | C^4D | b&4C a8D)~
Fag T1
C4E D&4F C8G5 E F E b&4C a&4b^ g8C
Cor T1
##-7 d4gb d4fa&C | d8gD | f4gF e&4f#E& | d8GD time T3;
Tr_be T1
D4f#
Tr_ni T1
C4e 8 g8c 16 g8c
Tuba T1
c4g 8 c8g 16 c8g
Perc T1
{lowTimpani} 8 {timpaniRoll,8} 16 {timpaniRoll,8}
P_no T1 @@6
1 g2CEG gCEG | 1 g2b&D&FG gb&D&FG | /2 f/gCF e/gCF f/gCF
e/gCE E/GC@E@ E/GC@E@ E&/GC@E@ |E/GC@E@ C/EGC@ G/C@ C/G C/G
g/C g/C c/g | 1 e2b&C ebc | 1 d2fB^ dfb | /2 f/gCF e/gCE f/gCF
e/gCE F/GC@F@ E/GC@E@ F/GC@F@ E/GC@E@ C/EGC@
P_no T1 @@4
cc@ E2GC@E@ EGC@E@ | cc@ F2B&D&@F@ FBD@F@ | /2 g/CF g/CE
g/CF g/CE E/GC@E@ E/GC@E@ E&/GC@E@ | E/GC@E@ E/GC@ G/C@ c/G c/G
g/C g/C | cc@ C2B&C@ CBC@ | cc@ C2A&B CA&B | /2 g/CF g/CE g/CF
g/CE F/GC@F@ E/GC@E@ F/GC@F@ E/GC@E@ E/GC@
Bass T1
c4 c4 c8 c4 c4 c8
set [ theme1 {C D D# | E5 C E F G F E3 }
theme2 {@@+1 g C D E F2 E E3 D C b a C } ]
Fl_Ob_StringsEns T2
theme1 'bar 13.5 or so
Cl T2
| (key D C4E | b4D | E2G D4F ) ##+2
Fag T2
| b4D a4C D2F C4G
Cor T3
b7@f#4a4b7 e4g 3 Cc | d8a2C2D8 b6g
P_no T2 duration /2 @@6
GC@ CG CG gC GC CG | 2 e6bde | 2 a4@ce c2ac |
2 g2@dfg 4 g4CEG 'g4CEG g2@cg
P_no T2 @@4 GC@ CG CG gC gC cg | g#2g@ E6BD@ | a2a@ a4E e2A |
b2b@ g2df c2c@ E4GC@E@
time T1 duration 1
Bass
@@-1 g#4 a4 b2 C6
'----------------------------------------------------------------------
Fl_StringsEns T1
theme2
Ob_Cl_FagEns T1
1 E2G D4G# | C4A C4D
Cor T1
| a4D# | g4E g4a ##+7
Tr_ni T1
| g#4D | a4C | a4C
Tuba T1
| e4D | f4C | f#4D
P_no T1 @@6 duration
/2 g2@cg | 1 DG#D@ CGC@ DGD@ CGC@ CGC@ bGB CGC@ |
1 CFC@ bFB CFC bFB aFA aFA fC | 1 aDA aDA aD 2 daD daD da |
P_no T1 @@4
gC | 1 ( DG# )7(D@ C@ D@ C@ B C@) | 1 ( CF )7( C@ B C@ B A A A) |
1 AD@ aD@ DA 2 DA DA f#D
duration 1 time T1;
Bass E4 F4 F4#
'----------------------------------------------------------------------
Fl_StringsEns T1 'bar22 or so
g C E G |A& A^2 A& | A& D E F | G A^2 G | G C# D E | E F F E
E D D E |E2 D C | C e e d |
Ob_ClEns T1
C2E EG GC@ | G&4C@ | F4C@ | F4B3 B& | G4A | D4A | D4G# | F4A | C4D
Fag_CorEns T1
C2E E2G | g&4A&1 A^2 A& | F4A& | F4G1 A2^ G | E4G | a4D | g#4D | a8C
Tr_be T1
20 | b4 a#4 g4b e4
Tr_ni T1
g4C g&4C f4C f4b3 b& | g4a a4D b4D a8C
Tuba T1
g4E a&4@a d4D g4@g | a4@a d4D | e4E f4F f#4F
Perc T1
28 {timpaniRoll,8}
P_no @@6 duration /2
| 1 CEGC@ CEGC@ gCEG 2 gCEG gCEG egCE
| 1 @@+1 a&CG&A a^CGA aCGA aCGA a&CGA aCGA gG
| 2 a&4@cea a2CFA
| 1 gbFG a^bFA abFA abFA gbFG gb&FG fF
| 2 g4@c#eg g2C#EG
| 1 aDA aDA daD daD da a@da a@da
| 1 g#DG gDG dgD dgD dg g@dg g@d
| 2 a2@@c@f@a@ a2@cfa a2CFA
| 2 d4@a@c d2aCD
P_no T1 @@4
| 1 EGC@E EGC@E cEGC 2 cEGC cEGC gCEG @@+1
| a&@a@@ aCG&A a^CGA aCGA aCGA a&CGA aCGA gG
| d2@d@@ f4a&CF F2AC@F@
| g@g@@ gbFG a^bFA abFA abFA gbFG gb&FG fF
| a2@a@@ e4GC#E E2GC#@E@
| d@d@@ aDA aDA fCF fCF fC cFC cF
| e@e@@ g#DG gDG dgD dgD dg g@DG gD
| f2@f@@ f2@a@cf f2aCF F2AC@F@
| f2#@f@@ d4aC a2CDA
Bass duration 1
| G4 A4& D4 G4 a4 D4 E4 F4 F#4
time T1
'-----------------------------------------------------------------------
restart
set [
stac {**/3}
leg {**1}
]
+ tempo=160
Orchestra stac !!+20 'PUT WHOLE ORCHESTRA INTO LOUD STACCATO MODE
Fl
CG | 3 f#C |gD aE& b&E^ b^F^ |CG GA F#A F^B | EC@
3fg | eC 3 a&C | g#E a^C# aD D@A | leg C2G4 b2 | stac C
3a&C | gE 3 aD# | EG C#A DA AD | leg !+20 C^2G4 b2
Ob
EG | 3 f#C |gD aE& b&E^ b^F^ |CG GA F#A F^B | EC@
3fg | eC 3 a&C | g#E a^C# aD D@D | leg C2G4 b2 | stac C
3a&C | gE 3 aD# | EG C#A DA AD | leg !+20 C^2G4 b2
Cl (key D ##-2
FA | 3 eg# |eg ab aC^ aC# |aD DA DG# CG^ | DF
3cg| df 3 d | e fb eb eD | leg g4G stac | fD 3
de | df 3 bC | aC bD# bE bE | leg g4G stac)
Fag
EG | 3 aD |bD CG C#G DG |EG E&C@ DC@ GD@ debug_off
| cC@ leg a2 stac gG@ | CG leg E2 stac FA& |
| EB# aA^ fF bC | leg g4G | stac cC leg E2 stac
FA& | CG leg A2 stac BD#@ | EE@ aA fF f#F | leg
g4G |
Cor ##-7
dgbD | 3 c#agC# dCaD db&eD db^fD dCf#D | dDgD gDE gC#E f#C^D |
dgb leg c#2gb c^fC | 1 a2e&E& geE | 1 stac g#eE aeE eag |
leg d4g2C4D f#2 | stac dgb leg e&2Ea stac eEg | 1 leg b2C#G
stac a#F#E | 1 g#Ee aeE eEa | leg d4CDg2 f#2
Tr_be
aD | 1 | 1 | 1da dg# g^C# | f#D | 8 | leg a4 | d | 8 a4
Tr_ni
CE | 11 gb | gC | 8 | leg g4D2 C2 | eC | f4C2 b2 |
Tuba
gG | 10 dD gG | cC | 8 | leg g4g@ | cC | 8 g4g@ |
Perc
{lowTimpani} | 8 | 3 {lowTimpani} | {highTimpani} |
8 | {timpaniRoll,4} | {highTimpani}
Violin1
g@eCG | 3 dC | dD E& E^ F | G aA aA DB | EC@ leg e2 stac g
eC leg g#2 stac C | E C# D A | leg G4 | C g#2 C | stac
CE leg C2 stac D# | G aA aA aD@ | leg G4
Violin2
g@eC | 3 f# | f^g@ gg@ gg@ gg@ | gg@ ga f#a f^ |
G@Ec leg C2 stac G@F | G@E leg D2 stac a& | g# ea da dD |
leg d4C2 b2 | eC leg d2 stac a& | g@g leg f#2 stac a
| bE C# D aA | leg d4C2 b2
Viola
gEC@ | 3 f# | g a b& b^ | C cC cC gD | cgE
leg f#2 stac g | gE g#2D C | g#D E D DA | leg g4F stac
| ge leg g#2 stac C | gE leg E2 stac D#A | E C# D DA |
leg g4F |
Cello
g | 3 a | b C C# D | E E&A dA G | C leg a2 stac g |
C leg E2 stac F | E A F F# | leg G4 stac C leg E2 stac F
|C leg A2 stac B | E A GA G#A | leg G4 |
Bass
g | 3 a | b C C# D | E E&A dA G | C leg a2 stac g |
C leg E2 stac F | E A F F# | leg G4 stac | C leg E2 stac
F | C leg A2 stac B | E A F F# | leg G4
P_no duration /3 @@6 (tempo=160 48+40)
(| 1 CEG g 2CEA a 2EGB b 2EGC@ C |)
| ce g@ 2a@ce g@ 2be g@ 2ce g@ |
(| 1 GC@D@ D 2GC@E@ E 2 C@D@F#@ F |)
| cdg g@ 2ceg g@ 2 cf a@ 2cdf# a@ |
(| 1 D@F@G@ G 2 G@@ G@ 2 G@ G 2 G g|)
| df^g b 2 G g 2 g g@ 2g@ g@@ |
(| 24| )
| g@ | 3 @@5 e f#CF# g aCA g aCA b baDA b
| C3EC@ g# aDA b CC@ b CC@ D CA&C@ D
(| @@6 e3g#E 4 C#g^ c 2 aD d 2 C^DA a)
| 3 a@ e 2 f@a@ d 2 f#@c d
(|@@7 1 cdg g@ 2CDG g bDG g b@dg g@ )
|@@6 g@c d 2 gC D 2 gb D 2 b@g@ f
|@@6 C3ce g#@ a@da b@ cC b@ cC d ca&C d
|e3gE c df#D d# efE d efeE f# eaE f#
|g3bG a@e gC#GA a f@a@d fDA a f#@a@d f#AC^@D@
|b@cd f^CDG g gCD FC@D@G@ G gbD FBD@G@ G gdF GB@D@@G@@ G@
'-----------------------------------------------------------------------
restart duration 1
set rhythm { stac ?1 2 leg *2 ?2 | stac ?3 2 leg *2 ?4 |
stac ?5 2 leg *2 ?6 | stac ?7 ?8 ?9 ?a | ?b 4 | ?c 2 ?d 2 |
?e 2 ?f ?g | ?h 2 ?i | ?j 2 ?k */ ?k */ ?k ?k};
Fl
{rhythm,C,CE,C,DE,C,bE,C,CE,aC,bE,
C,GC@,GC@,GC@,GC@,GC@,GC@,DG,GC@, }
Ob
{rhythm,C,CE,C,DE,C,bE,C,CE,aC,bE,
C,GC@,GC@,GC@,GC@,GC@,GC@,DG,GC@, }
Cl (key D
{rhythm,dD,fg#,fa,fC,fa,fC,fa,fb,df,fC,
fa,FD@,FD@,FD@,FD@,FD@,FD@,CA,FD@,a@d} )
Fag
{rhythm,CC@,AC@,GC@,G#B,G^C@,GB,GC@,AC@,AC@,EC@,
CC@,C@E@,C@E@,C@E@,C@E@,C@E@,C@E@,D@G@,C@E@,CE}
Cor
{rhythm,g,bC#,bD,ab,bD,bD,bD,bE,gb,bD,
bD,gbDG,gbdG,gbDG,gbDG,gbDG,gbDG,f#DaF#,gDbG,g@db@g}
Tr_be
{rhythm,d,DF#,f#D,C#F#,f#D,C#F#,f#D,DF#,bD,C#F#,
f#D,f#D,f#D,f#D,f#D,f#D,f#D,ea,f#D,d}
Tr_ni
{rhythm,eC,f#C,gC,eb,gC,eb,gC,ac,ac,eb,
gC,gC,gC,gC,gC,gC,gC,gb,gC,fa}
Tuba
{rhythm,cC,g@g,cC,g#@g,cC,g^@g,cC,f#,a,g,
cC,cC,cC,cC,cC,cC,cC,gG,cC,cC}
Perc
highTimpani | 8 | 1 highTimpani highTimpani lowTimpani |
highTimpani | (highTimpani 2 )3~ (highTimpani )3~ 1
lowTimpani | highTimpani 2 highTimpani {highTimpani}/2
{highTimpani}/2 | highTimpani
ViolinEns
{rhythm,C,eCE,EC,eDE,EC,egE,eC,eCE,eC,ebE,
eC,cgEC@,cgEC@,cgEC@,EC@,EC@,EC@,g@dbG,geCC@,c,g@}
Viola
{rhythm,C,f#,eg,e,eg,eg,eg,a,a,eb,
cC,cgEC@,cgEC@,cgEC@,EC@,EC@,EC@,gDB,cgEC@,e}
Cello
{rhythm,C,a,C,g#,C,g^,C,f#,a,g,
cC,cgEC@,cgEC@,cgEC@,cC,cC,cC,gDB,cgEC@,cC}
Bass
{rhythm,C,a,C,g#,C,g^,C,F#,A,G,
C,C,C,C,C,C,C,G,C,C}
set [gen { ?1 ?2 ?1 ?2 }
gen2 { ?1 *2 ?1 }]
P_no @@6 duration /4
C4EC@ {gen,
CEGC@, @+1 E@GC@E@,aEF#A,@+1 CEAC,f#CE,@+1 aCEA,
gCE,@+1 gCEG,cegC,EGC@E@,b@deb,EBD@E@,g#@deg#,bDEB,
g^@ceg,CEGC@,g@CE,gCEG,g@bE,gbE,e@g@b@,egb,
e@g@c,egC,c@e@a@,cea} @@-1 {gen,a@ce,aCE,g@be,gbE}
duration /3 |
(1 gC e2 {gen2,CEA,CEG,EGD@,EGC@,C@E@A@,C@E@G@,E@G@D@@} @@6
{gen2,egC,CEA,CEG,EGD@,EGC@,C@E@A@,BD@G@,F@G@D@@} 1 E@G@C@@
@@5 (duration 1 2 cC c/C c/C cC))
c3egC a3@cea g3@ceg d3egD | c3egC a3CEA g3CEG D3EGD@ |
C3EGC@ A3C@E@A@ G3C@E@G@ D3@E@G@D@@ C3@E@G@C@@ A3@C@@E@@A@@ @@+1
G3D@F@G@ D3@F@G@D@@ C@E@G@C@@
@@4 (duration 1 2 cc@ c/c@ c/c@ cc@)
